Program 11.3 Estimation of Transition Probabilities

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* STEP 3: Estimate transitional probabilities of the longitudinal \*;

\* propensity score strata. The first part of this section creates \*;

\* an analysis data set with variables to denote the propensity \*;

\* score bin and treatment at each visit (data set UPD which is then \*;

\* merged with visitwise analysis data sets). Summary statistics on \*; \* the propensity score bins and treatments over time can be easily \*;

\* summarized using PROC FREQ. The EST macro runs a proportional \*;

\* odds logistic regression model to assess the transitional \*;

\* probabilities for each possible combination of propensity bin \*;

\* over time. The steps following the macro compute the transition \*;

\* probabilities from the parameter estimates of the logistic model \*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* Input for macro denotes the visit number \*;

**%MACRO** PM(VN);

DATA F1\_&VN;

SET &VN;

BIN\_PS\_&VN = BIN\_PS;

TRT\_&VN = TRT;

KEEP PATSC BIN\_PS\_&VN TRT\_&VN;

RUN;

**%MEND** PM;

%***PM***(V5); **RUN**;

%***PM***(V6); **RUN**;

%***PM***(V7); **RUN**;

**PROC** **SORT** DATA = F1\_V5; BY PATSC; **RUN**;

**PROC** **SORT** DATA = F1\_V6; BY PATSC; **RUN**;

**PROC** **SORT** DATA = F1\_V7; BY PATSC; **RUN**;

**DATA** UPD;

MERGE F1\_V5 F1\_V6 F1\_V7;

BY PATSC;

**PROC** **FREQ** DATA = UPD;

TABLES BIN\_PS\_V5\*BIN\_PS\_V6\*BIN\_PS\_V7;

TITLE 'PATTERN OF BINS OVER TIME'; **RUN**;

**PROC** **FREQ** DATA = UPD;

TABLES TRT\_V5 TRT\_V6 TRT\_V7 TRT\_V5\*TRT\_V6\*TRT\_V7;

TITLE 'PATTERN OF TRTS OVER TIME'; **RUN**;

**PROC** **SORT** DATA = UPD; BY PATSC; **RUN**;

**PROC** **SORT** DATA = V5; BY PATSC; **RUN**;

**PROC** **SORT** DATA = V6; BY PATSC; **RUN**;

**PROC** **SORT** DATA = V7; BY PATSC; **RUN**;

**DATA** V5;

MERGE V5 UPD;

BY PATSC;

**DATA** V6;

MERGE V6 UPD;

BY PATSC;

**DATA** V7;

MERGE V7 UPD;

BY PATSC;

ODS LISTING CLOSE;

/\* Input for macro includes the analysis data set for a specific visit (INDAT), name for the output data set containing the parameter estimates (PARM\_EST), list of variables for the CLASS statement (CLASSVARS), and list of variables in the MODEL statement (MODELVARS). Run macro for the 2nd and 3rd time points to assess transitions. \*/

**%MACRO** EST(INDAT, PARM\_EST, CLASSVARS, MODELVARS);

PROC LOGISTIC DATA = &INDAT OUTEST = &PARM\_EST;

CLASS &CLASSVARS;

MODEL BIN\_PS = &MODELVARS;

RUN;

**%MEND** EST;

%***EST***(V6, PARM\_V6, TRT\_V5 BIN\_PS\_V5, TRT\_V5 BIN\_PS\_V5); **RUN**;

%***EST***(V7, PARM\_V7, TRT\_V5 BIN\_PS\_V5 TRT\_V6 BIN\_PS\_V6, TRT\_V5 BIN\_PS\_V5 TRT\_V6 BIN\_PS\_V6); **RUN**;

ODS LISTING;

/\* Data trpr\_v7 uses the parameter estimates output from the EST macro to compute the actual transition probabilities for time period 2 to 3. Arrays are used in order to more efficiently calculate the 250 different transition probabilities (5x5x5x2: 5 propensity bins at each of 3 time points for each of two treatment patterns of interest). \*/

**DATA** TRPR\_V7;

SET PARM\_V7;

IF \_TYPE\_ = 'PARMS';

\* parameters are set to zero automatically in SAS modeling and are

specifically set to zero here for clarity. \*;

INTERCEPT\_5 = **0**;

BIN\_PS\_V55 = - BIN\_PS\_V51 - BIN\_PS\_V52 - BIN\_PS\_V53 - BIN\_PS\_V54;

BIN\_PS\_V65 = - BIN\_PS\_V61 - BIN\_PS\_V62 - BIN\_PS\_V63 - BIN\_PS\_V64 ;

TRT\_V5T\_2 = - TRT\_V5T\_1;

TRT\_V6T\_2 = - TRT\_V6T\_1;

X1 = INTERCEPT\_1;

X2 = INTERCEPT\_2;

X3 = INTERCEPT\_3;

X4 = INTERCEPT\_4;

X5 = INTERCEPT\_5;

Y1= BIN\_PS\_V51;

Y2= BIN\_PS\_V52;

Y3= BIN\_PS\_V53;

Y4= BIN\_PS\_V54;

Y5= BIN\_PS\_V55;

Z1= BIN\_PS\_V61;

Z2= BIN\_PS\_V62;

Z3= BIN\_PS\_V63;

Z4= BIN\_PS\_V64;

Z5= BIN\_PS\_V65;

W1= TRT\_v5T\_1;

W2= TRT\_v5T\_2;

V1= TRT\_v6T\_1;

V2= TRT\_v6T\_2;

run;

**DATA** TRPR\_V7;

SET TRPR\_V7;

ARRAY X[**5**] X1 - X5;

ARRAY Y[**5**] Y1 - Y5;

ARRAY Z[**5**] Z1 - Z5;

ARRAY W[**2**] W1 - W2;

ARRAY V[**2**] V1 - V2;

ARRAY PRE[**5**, **5**, **5**, **2** ];

DO A = **1** TO **2**; \* LOOP FOR 2 TREATMENT GROUPS \*;

DO I = **1** TO **5**; \* LOOP FOR BINS AT TIME PERIOD 3 \*;

DO J = **1** TO **5**; \* LOOP FOR BINS AT TIME PERIOD 1 \*;

DO K = **1** TO **5**; \* LOOP FOR BINS AT TIME PERIOD 2 \*;

\* Computation of probabilities using logistic model. Initial (pre)

probabilites are cumulative as they are from proportional odds

model - and are adjusted to individual outcome probabilities here\*;

PRE[I, J, K, A ]= EXP(X[I] + W[A] + V[A] + Y[J] + Z[K]) / (**1** +

EXP(X[I] + W[A] + V[A] + Y[J] + Z[K]));

TRPR7 = PRE[I, J, K, A ];

IF **2** LE I LE **4** THEN DO;

TRPR7 = PRE[I, J, K, A ] - (EXP(X[I-**1**] + W[A] + V[A] + Y[J] +

Z[K]) / (**1** + EXP(X[I-**1**] + W[A] + V[A] + Y[J] +

Z[K])));

END;

IF I = **5** THEN DO;

TRPR7 = **1** - (EXP(X[I-**1**] + W[A] + V[A] + Y[J] + Z[K]) / (**1** +

EXP(X[I-**1**] + W[A] + V[A] + Y[J] + Z[K])));

END;

OUTPUT;

END;

END;

END;

END;;

KEEP A I J K TRPR7;

\* Repeat the same process for trpr\_v6 as for trpr\_v7. Here there are 50 transitional probabilities to compute. \*;

**DATA** TRPR\_V6;

SET PARM\_V6;

IF \_TYPE\_ = 'PARMS';

INTERCEPT\_5 = **0**;

BIN\_PS\_V55 = - BIN\_PS\_V51 - BIN\_PS\_V52 - BIN\_PS\_V53 - BIN\_PS\_V54;

TRT\_V5T\_2 = - TRT\_V5T\_1;

X1 = INTERCEPT\_1;

X2 = INTERCEPT\_2;

X3 = INTERCEPT\_3;

X4 = INTERCEPT\_4;

X5 = INTERCEPT\_5;

y1= BIN\_PS\_V51;

y2= BIN\_PS\_V52;

y3= BIN\_PS\_V53;

y4= BIN\_PS\_V54;

y5= BIN\_PS\_V55;

z1= TRT\_V5T\_1;

z2= TRT\_V5T\_2;

**run**;

**DATA** TRPR\_V6;

SET TRPR\_V6;

ARRAY X[**5**] X1 - X5;

ARRAY Y[**5**] Y1 - Y5;

ARRAY Z[**2**] Z1 - Z2;

ARRAY PRE[**5**, **5**, **3** ]; /\* it is a three-dimensional array \*/

DO A = **1** TO **2**;

DO K = **1** TO **5**;

DO J= **1** TO **5**;

PRE[K, J, A]= EXP(X[K] + Y[J] + Z[A]) / (**1** + EXP(X[K] + Y[J] +

Z[A]));

TRPR6 = PRE[K, J, A];

IF **2** LE k LE **4** THEN DO;

TRPR6 = PRE[K, J, A] - (EXP(X[K-**1**] + Y[J] + Z[A]) / (**1** +

EXP(X[K-**1**] + Y[J] + Z[A])));

END;

IF K = **5** THEN DO;

TRPR6 = **1** - (EXP(X[K-**1**] + Y[J] + Z[A]) / (**1** + EXP(X[K-**1**] +

Y[J] + Z[A])));

END;

OUTPUT;

END;

END;

END;

KEEP A J K TRPR6 SECTION6; RUN;